предлагаю сделать невозможным поднять оружие с земли

[ptaha525]

предлагаю сделать невозможным поднять оружие с земли.
пример карты fy_snow оружие на земле или игрок с флагом amx_restrflag "b" бросил оружие
игрок без флага B не мог его поднять.

 

[борис]

пример карты fy_snow

Я извиняюсь конечно, но за чем на этой карте делать запрет на поднятие оружия даже с флагом доступа, вы бы еще поставили запрет на всех классичиских картах в том числе на aim_map

 

[SergeyPanov]

@борис, а действительно, как запретить поднимать оружия?)

 

[борис]

@борис, а действительно, как запретить поднимать оружия?)

Какое оружие? Обычное или по приве?

Сообщение автоматически объединено: 13 Мар 2025

Именно на этих картах?

 

[ptaha525]

@SergeyPanov,

Спойлер: test

#include <amxmodx>
#include <hamsandwich>
#include <cstrike>
#include <fakemeta>
#include <engine>
#include <reapi>

#define MAX_PLAYERS 32
new cstAWPCount[CsTeams], pLimit, pAllowPickup, PlayersWithAWP[CsTeams], Float:fFlood[MAX_PLAYERS+1];

#define IsPlayer(%1) (1<=%1<=MAX_PLAYERS)

public plugin_init()
{
    register_event("TextMsg", "EventRestart", "a", "2&#Game_C", "2&#Game_w");
   
    RegisterHam(Ham_AddPlayerItem, "player", "AddPlayerItem");
    RegisterHookChain(RG_CBasePlayer_HasRestrictItem, "HasRestrictItem", false)

    register_touch("weaponbox", "player", "PlayerTouchWeapon");
    register_touch("armoury_entity", "player", "PlayerTouchWeapon");
   
    register_forward(FM_SetModel , "SetModel");
   
    pLimit = register_cvar("bot_limit", "1");
    pAllowPickup = register_cvar("bot_allowpickup", "1");
}

public SetModel(iEntity, const szModel[])
{  
    new iPlayer, CsTeams:cstTeam;

    if((equal(szModel, "models/w_g3sg1.mdl") || equal(szModel, "models/w_sg550.mdl")) && IsPlayer((iPlayer = pev(iEntity, pev_owner))))
    {
        cstTeam = cs_get_user_team(iPlayer);
        cstAWPCount[cstTeam]--;
        PlayersWithAWP[cstTeam] &= ~(1 << (iPlayer & 31));
    }
}

public AddPlayerItem(iPlayer , iItem)
{  
    new CsTeams:cstTeam;
   
    if(cs_get_weapon_id(iItem) == CSW_G3SG1 || cs_get_weapon_id(iItem) == CSW_SG550)
    {
        cstTeam = cs_get_user_team(iPlayer);
        cstAWPCount[cstTeam]++;
        PlayersWithAWP[cstTeam] |= (1 << (iPlayer & 31));
    }
}

public PlayerTouchWeapon(iTouched, iToucher)
{
    new szClass[32], iWeaponID, CsTeams:cstTeam, bool:bBlocked, Float:fGameTime;

    if(get_pcvar_num(pAllowPickup))
        return PLUGIN_CONTINUE;

    entity_get_string(iTouched, EV_SZ_classname, szClass, charsmax(szClass));

    iWeaponID = (szClass[0] == 'w') ? cs_get_weaponbox_type(iTouched) : cs_get_armoury_type(iTouched);

    if(iWeaponID == CSW_G3SG1 || iWeaponID == CSW_SG550)
    {
        cstTeam = cs_get_user_team(iToucher);

        if(cstAWPCount[cstTeam] == get_pcvar_num(pLimit))
        {
            if(((fGameTime = get_gametime()) - fFlood[iToucher]) >= 5.0)
            {
                client_print(iToucher, print_center, "Your team has reached its limit!");
                fFlood[iToucher] = fGameTime;
                bBlocked = true;
            }
        }
    }
    return bBlocked ? PLUGIN_HANDLED : PLUGIN_CONTINUE;
}

public HasRestrictItem(const this, ItemID:item, ItemRestType:type)
{
    if(type == ITEM_TYPE_BUYING || ITEM_TYPE_TOUCHED || ITEM_TYPE_EQUIPPED)
    {
        switch(item)
        {
            case ITEM_G3SG1, ITEM_SG550:
            {
                new CsTeams:cstTeam = cs_get_user_team(this);
               
                if(!(get_user_flags(this) & ADMIN_BAN))
                {
                    client_print(this, print_center, "This gun ONLY ADMIN!");
                    SetHookChainReturn(ATYPE_BOOL, true);
                    return HC_SUPERCEDE;
                }
                else if(cstAWPCount[cstTeam] == get_pcvar_num(pLimit))
                {
                    client_print(this, print_center, "Your team has reached its limit!");
                    SetHookChainReturn(ATYPE_BOOL, true);
                    return HC_SUPERCEDE;
                }
            }
        }
    }
    return HC_CONTINUE;
}

public client_disconnected(id)
{
    for(new CsTeams:cstTeam = CS_TEAM_T ; cstTeam <= CS_TEAM_CT ; cstTeam++)
    {
        if(PlayersWithAWP[cstTeam] & (1 << (id & 31)))
        {
            cstAWPCount[cstTeam]--;
            PlayersWithAWP[cstTeam] &= ~(1 << (id & 31));
            break;
        }
    }
}

stock cs_get_weaponbox_type(iWeaponBox)
{
    new iWeapon;
    new const XO_CWEAPONBOX = 4;
    new const m_rgpPlayerItems_CWeaponBox[6] = { 34 , 35 , ... };
   
    for(new i = 1 ; i <= 5 ; i++)
    {
        if((iWeapon = get_pdata_cbase(iWeaponBox , m_rgpPlayerItems_CWeaponBox[i] , XO_CWEAPONBOX)) > 0)
        {
            return cs_get_weapon_id(iWeapon);
        }
    }
    return 0;
}

public EventRestart()
{
    cstAWPCount[CS_TEAM_T] = 0;
    cstAWPCount[CS_TEAM_CT] = 0;
    PlayersWithAWP[CS_TEAM_T] = 0;
    PlayersWithAWP[CS_TEAM_CT] = 0;
}